;HYBRID OP-WALL SOLUTION
; by EFnet #mirc ops, updated Apr 22, 2001
; This installs the alias /wall6 as a universal replacement for /onotice,
; which doesn't work on some IRC servers/networks due to anti-spamming features.
; This script should work with mIRC 5.82 or later, and has been tested on:
;    EFnet, IRCnet, Undernet, DALnet, Galaxynet, and OpenProjectsNet
; Save this file to your mIRC directory, and /load -rs Onotice.mrc
; Then disconnect and reconnect to the server to make it work the first time.
;
RAW 2:*:{
  VAR %hyb5 = *2.8/hybrid-5*
  VAR %hyb6 = *2.8/hybrid-6*
  VAR %co01 = *2.8/comstud-1.0*
  VAR %co11 = *2.8/comstud-1.11-REL*
  VAR %dl46 = *dal4.6*
  VAR %bahx = *bahamut*

  IF ((%hyb5 ISWM $1-) || (%co01 ISWM $1-)) { SET %nettype 1 | ECHO $colour(info text) -s *** Setting OP-WALL mode to 1 (multiple recipients) }
  ELSEIF (%hyb6 ISWM $1-) { SET %nettype 2 | ECHO $colour(info text) -s *** Setting OP-WALL mode to 2 (2 recipients per send) }
  ELSEIF (%co11 ISWM $1-) { SET %nettype 3 | ECHO $colour(info text) -s *** Setting OP-WALL mode to 3 (1 recipient per send) }
  ELSEIF ((%dl46 ISWM $1-) || (%bahx ISWM $1-)) { SET %nettype 4 | ECHO $colour(info text) -s *** Setting OP-WALL mode to 4 (multiple recipients) }
  ELSE { SET %nettype 0 | ECHO $colour(info text) -s *** The network you are connected to is unidentified. Reverting to default /onotice. }
}

ALIAS WALL6 {
  if ($active !ischan) { echo $colour(info text) -a *** You're not in a channel. | halt }
  if ($me !isop $active) { echo $colour(info text) -a *** You do not have operator status in $active $+ . | halt }

  VAR %contents = @ $+ $lower(#) $1-
  VAR %nick,%nicks = 1

  IF (%nettype == 1) { | ;No limit
    .onotice %contents
    echo $colour(notice text) -ta - $+ $me $+ - %contents
  }
  ELSEIF (%nettype == 2) { | ;MAX 2
    WHILE (%nicks <= $nick($chan,0,o)) {
      %nick = $nick($chan,%nicks,o) $+ $iif($nick($chan,$calc(%nicks + 1),o) != $null,$chr(44) $+ $nick($chan,$calc(%nicks + 1),o))
      .notice %nick %contents
      INC %nicks 2
    }
  }
  ELSEIF (%nettype == 3) { | ;MAX 1
    WHILE (%nicks <= $nick($chan,0,o)) {
      .notice $nick($chan,%nicks,o) %contents
      inc %nicks
    }
  }
  ELSEIF (%nettype == 4) { | ;No limit
    .notice @ $+ $active %contents
    echo $colour(notice text) -ta - $+ $me $+ - %contents
  }
  ELSE { | ;Unidentified
    .onotice $active %contents
    echo $colour(notice text) -ta - $+ $me $+ - %contents
  }
}